Add support for manpages via mandoc

.travis.yml

@@ -13,8 +13,9 @@ git:
 before_install:
   - sudo apt-key adv --keyserver hkp://keyserver.ubuntu.com:80 --recv 379CE192D401AB61
   - echo "deb https://dl.bintray.com/nxadm/rakudo-pkg-debs `lsb_release -cs` main" | sudo tee -a /etc/apt/sources.list.d/rakudo-pkg.list
+  - sudo add-apt-repository ppa:jordemort/mandoc -y
   - sudo apt-get update -qq
-  - sudo apt-get install perl rakudo-pkg
+  - sudo apt-get install mandoc perl rakudo-pkg xmlstarlet
   - export PATH=$PATH:/.perl6/bin:/opt/rakudo-pkg/bin
   - curl -L http://cpanmin.us | perl - --sudo App::cpanminus
   - sudo cpanm --installdeps --notest Pod::Simple

README.md

@@ -29,6 +29,7 @@ you wish to run the library. You can also run `script/bootstrap` to fetch them a
 * [.asciidoc, .adoc, .asc](http://asciidoc.org/) -- `gem install asciidoctor` (http://asciidoctor.org)
 * [.pod](http://search.cpan.org/dist/perl/pod/perlpod.pod) -- `Pod::Simple::XHTML`
   comes with Perl >= 5.10. Lower versions should install Pod::Simple from CPAN.
+* [.mdoc](http://mandoc.bsd.lv/man/mdoc.7.html), [.man](http://mandoc.bsd.lv/man/man.7.html) -- `apt-get` or `brew install mandoc xmlstarlet` (http://mandoc.bsd.lv/ http://xmlstar.sourceforge.net/)
 
 Installation
 -----------

lib/github/commands/man2html

@@ -0,0 +1,11 @@
+#!/usr/bin/env bash
+set -e
+
+# process it, and print everything from the first <h1> to </body>
+mandoc -Thtml -Ofragment "$@" \
+| xml -q tr --html --omit-decl  "$(dirname "$0")/man2html.xslt" - \
+| awk '
+	/<h1/      { flag = 1 }
+	/<\/body>/ { flag = 0 }
+	flag
+'

lib/github/commands/man2html.xslt

@@ -0,0 +1,114 @@
+<?xml version="1.0" encoding="utf-8"?>
+<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
+
+  <!-- Default: match anything and apply templates to it -->
+  <xsl:template match="node()|@*">
+    <xsl:copy>
+        <xsl:apply-templates select="node()|@*"/>
+    </xsl:copy>
+  </xsl:template>
+
+  <!-- Strip all the attributes off of these -->
+  <xsl:template match="h1">
+    <h1><xsl:apply-templates /></h1>
+  </xsl:template>
+
+  <xsl:template match="h2">
+    <h2><xsl:apply-templates /></h2>
+  </xsl:template>
+
+  <xsl:template match="h3">
+    <h3><xsl:apply-templates /></h3>
+  </xsl:template>
+
+  <!-- Turn these into paragraphs -->
+  <xsl:template match="div[@class='Pp']">
+    <p><xsl:apply-templates /></p>
+  </xsl:template>
+
+  <!-- Indent these -->
+  <xsl:template match="div[@class='Bd-indent' or @class='Bd Bd-indent']">
+    <ul><xsl:apply-templates /></ul>
+  </xsl:template>
+
+  <!-- Headers don't need to be linking to themselves -->
+  <xsl:template match="a[@class='permalink']">
+    <xsl:apply-templates />
+  </xsl:template>
+
+  <!-- SHOUTING_SNAKE_CASE → calm-kebab-case -->
+  <xsl:template match="a[@class='Sx']">
+    <xsl:variable name="href" select="
+      translate(@href, 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_',
+                       'abcdefghijklmnopqrstuvwxyz-')" />
+    <a href="{$href}"><xsl:apply-templates select="node()" /></a>
+  </xsl:template>
+
+  <!-- Pull the manual-text div out -->
+  <xsl:template match="div[@class='manual-text']">
+    <xsl:apply-templates />
+  </xsl:template>
+
+  <!-- These were display: inline, so just give the content -->
+  <xsl:template match="div[@class='Nd' or @class='Bf' or @class='Op']">
+    <xsl:apply-templates />
+  </xsl:template>
+
+  <!-- These were display: italic -->
+  <xsl:template match="span[@class='Pa' or @class='Ad']">
+    <samp><xsl:apply-templates /></samp>
+  </xsl:template>
+
+  <!-- These were font-weight: bold -->
+  <xsl:template match="span[@class='Ms']">
+    <b><xsl:apply-templates /></b>
+  </xsl:template>
+
+  <xsl:template match="dl[@class='BL-diag']/dt">
+    <b><xsl:apply-templates /></b>
+  </xsl:template>
+
+  <xsl:template match="code[@class='Nm' or @class='Fl' or @class='Cm' or @class='Ic' or @class='In' or @class='Fd' or @class='Fn' or @class='Cd']">
+    <b><code><xsl:apply-templates /></code></b>
+  </xsl:template>
+
+  <!-- Monospace -->
+  <xsl:template match="var[@class='Ar']">
+      <code><var><xsl:apply-templates /></var></code>
+  </xsl:template>
+
+  <xsl:template match="a[@class='Xr']">
+    <code><xsl:apply-templates /></code>
+  </xsl:template>
+
+  <!-- Remove header table -->
+  <xsl:template match="table[@class='head']"/>
+
+  <!-- Reformat footer table and pull some header stuff into it -->
+  <xsl:template match="table[@class='foot']">
+    <hr/>
+    <table>
+      <xsl:apply-templates select="//td[text() and text() != '()' and @class='head-ltitle']"/>
+      <xsl:apply-templates select="//td[text() and text() != '()' and @class='head-vol']"/>
+      <xsl:apply-templates select="//td[text() and text() != '()' and @class='foot-os']"/>
+      <xsl:apply-templates select="//td[text() and text() != '()' and @class='foot-date']"/>
+    </table>
+  </xsl:template>
+
+  <!-- Turn head header/footer cells into rows -->
+  <xsl:template match="td[@class='head-ltitle']">
+    <tr><th>Title:</th><td><xsl:apply-templates /></td></tr>
+  </xsl:template>
+
+  <xsl:template match="td[@class='head-vol']">
+    <tr><th>Volume:</th><td><xsl:apply-templates /></td></tr>
+  </xsl:template>
+
+  <xsl:template match="td[@class='foot-date']">
+    <tr><th>Date:</th><td><xsl:apply-templates /></td></tr>
+  </xsl:template>
+
+  <xsl:template match="td[@class='foot-os']">
+    <tr><th>Manual:</th><td><xsl:apply-templates /></td></tr>
+  </xsl:template>
+</xsl:stylesheet>

lib/github/markup.rb

@@ -19,6 +19,7 @@ module Markups
     MARKUP_RDOC = :rdoc
     MARKUP_RST = :rst
     MARKUP_TEXTILE = :textile
+    MARKUP_MANPAGE = :manpage
     MARKUP_POD6 = :pod6
   end
 

lib/github/markups.rb

@@ -57,3 +57,5 @@
 
 command(::GitHub::Markups::MARKUP_POD6, :pod62html, /pod6/, ["Pod 6"], "pod6")
 command(::GitHub::Markups::MARKUP_POD, :pod2html, /pod/, ["Pod"], "pod")
+
+command(::GitHub::Markups::MARKUP_MANPAGE, :man2html, /(?:[1-9](?![0-9])[a-z_0-9]*|0p|n|man|mdoc)(?:\.in)?/, ["Roff Manpage"], "manpage")

script/bootstrap

@@ -1,4 +1,4 @@
-#!/bin/bash
+#!/usr/bin/env bash
 
 set -e
 

script/bootstrap.contrib

@@ -1,4 +1,4 @@
-#!/bin/bash
+#!/usr/bin/env bash
 
 set -e
 

script/cibuild

@@ -1,4 +1,4 @@
-#!/bin/bash
+#!/usr/bin/env bash
 
 set -e
 

test/markup_test.rb

@@ -66,10 +66,10 @@ def call
         f.close_write
         f.read
       end
-      assert_html_equal expected, actual, <<message
-#{File.basename expected_file}'s contents are not html equal to output:
-#{diff}
-message
+      assert_html_equal expected, actual, <<~message
+        #{File.basename expected_file}'s contents are not html equal to output:
+        #{diff}
+        message
     end
   end
 

test/markups/README.man

@@ -0,0 +1,6 @@
+.Dd $Mdocdate: March 23 1981 $
+.Dt README 1
+.Os GitHub
+.Sh README.man
+.Nm README
+.Nd This is an example readme in mandoc

test/markups/README.man.html

@@ -0,0 +1,23 @@
+<h1>README.man</h1>
+<p><b><code>README</code></b> — This is
+    an example readme in mandoc</p>
+
+<hr>
+<table>
+<tr>
+<th>Title:</th>
+<td>README(1)</td>
+</tr>
+<tr>
+<th>Volume:</th>
+<td>General Commands Manual</td>
+</tr>
+<tr>
+<th>Manual:</th>
+<td>GitHub</td>
+</tr>
+<tr>
+<th>Date:</th>
+<td>March 23, 1981</td>
+</tr>
+</table>